blob: 6c2de6463c174297eb6b9fc811430bfab8d2027e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer (Arch): Kyle Keen <keenerd@gmail.com>
# Contributor (Arch): Maarten Baert
# Maintainer: Tobias Dausend <throgh@hyperbola.info>
pkgname=simplescreenrecorder
_pkgbasename=ssr
pkgver=0.4.2
_debver=0.4.2
_debrel=2
pkgrel=1
pkgdesc='A feature-rich screen recorder that supports X11 and OpenGL.'
arch=('i686' 'x86_64')
url='https://www.maartenbaert.be/simplescreenrecorder/'
license=('GPL-3')
depends=('qt-base' 'qt-x11extras' 'ffmpeg' 'alsa-lib' 'mesa-libgl' 'glu'
'libx11' 'libxext' 'libxfixes' 'libxi' 'libxinerama'
'desktop-file-utils' 'gtk-update-icon-cache')
makedepends=('cmake' 'qt-tools' 'quilt')
source=("https://github.com/MaartenBaert/ssr/archive/refs/tags/${pkgver}.tar.gz"
"https://deb.debian.org/debian/pool/main/s/simplescreenrecorder/simplescreenrecorder_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('60b0127d7f82f294e5a8f015363e37a10b5492089a0178b07a5e383c7e4b857102ed2bda7a95e3c67293a255f892481aeaf4037c583320d68d463637348ed7f7'
'ac2accbbe4c7abaa3311cc756c74ba72cb513f1035dd2694628c126c576ae4e89ebdb5b6c941b46a5913aaf052c8b3fad163a93483599a5c790212987647a021')
install=simplescreenrecorder.install
prepare() {
cd ${_pkgbasename}-${pkgver}
if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
# Debian patches
export QUILT_PATCHES=debian/patches
export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
export QUILT_DIFF_ARGS='--no-timestamps'
mv "$srcdir"/debian .
quilt push -av
fi
}
build() {
cd ${_pkgbasename}-${pkgver}
cmake \
-Bbuild \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_BUILD_TYPE=Release \
-DWITH_QT5=on \
-DWITH_ALSA=on \
-DWITH_JACK=off \
-DWITH_PULSEAUDIO=off \
-DCMAKE_INSTALL_LIBDIR='lib' .
make -C build
}
package() {
cd ${_pkgbasename}-${pkgver}
make -C build DESTDIR="$pkgdir" install
install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}
|
