blob: 59dac5e0d94453205fa2a71ae4c36ac76bebbea6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Laurent Carlier <lordheavym@gmail.com>
# Contributor: Eric Bélanger
pkgname=lm-sensors
pkgver=3
pkgrel=2
pkgdesc="Collection of user space tools for general SMBus access and hardware monitoring"
arch=('x86_64')
url="https://hwmon.wiki.kernel.org/lm_sensors"
license=('GPL' 'LGPL')
depends=('bash' 'glibc')
makedepends=('rrdtool' 'perl')
optdepends=('rrdtool: for logging with sensord'
'perl: for sensor detection and configuration convert')
provides=('libsensors.so')
backup=('etc/sensors3.conf' 'etc/healthd.conf' 'etc/conf.d/sensord')
source=("https://github.com/$pkgname/$pkgname/archive/refs/tags/V${pkgver}-6-0.tar.gz"
healthd healthd.conf healthd.service sensord.conf)
sha512sums=('4e80361913aff5403f1f0737fd4f42cffe43cc170ef48fff3914c9952f71990739d723f7b0b8120d9a01bcbbc829e964cfbd0a5cf18508af8f8dc825b49860bf'
'4ebd29309682c16749dccc72333c82f89609d266e80e9c8e410fec9fd638d3f2a72ab33c7584625029119749021b4ef6d99fc2fe5f02f8a0827b753e57bad6cc'
'a567bb7a646ae5b8b04d56e41fd8501a10a8678cca17a2fa62c354ae524761aaeebe4852f67ac064ba2aac3470426b8033db452030e4e01a198c108e19f54f85'
'f6b5288837fc298744e5d6ed5eb438510c59df2705cb62b8aef9dbedf433eac341e1c4b1a5b5b638247c7e4247ae19fb709d461b0815cba08cac1f07414b012a'
'732306b13f912ff86fb9c7fa199ff7c50982083ead2ca9b5913f1a57226fd6be5df69e6ad3077a713b33930e4d932ba6522027e7e6a91880518ebdfc8c6b61d7')
validpgpkeys=('7CA69F4460F1BDC41FD2C858A5526B9BB3CD4E6A')
prepare() {
cd "${srcdir}"/$pkgname-$pkgver-6-0
sed -i 's|/etc/sysconfig|/etc/conf.d|' prog/{detect/sensors-detect,init/{sensord,lm_sensors}.service}
sed -i 's/EnvironmentFile=/EnvironmentFile=-/' prog/init/lm_sensors.service
}
build() {
cd "${srcdir}"/$pkgname-$pkgver-6-0
make PREFIX=/usr
}
package() {
cd "${srcdir}"/$pkgname-$pkgver-6-0
make PROG_EXTRA=sensord BUILD_STATIC_LIB=0 \
PREFIX=/usr SBINDIR=/usr/bin MANDIR=/usr/share/man DESTDIR="${pkgdir}" install
install -D -m755 "${srcdir}/healthd" "${pkgdir}/usr/bin/healthd"
install -D -m644 "${srcdir}/healthd.conf" "${pkgdir}/etc/healthd.conf"
install -D -m644 "${srcdir}/sensord.conf" "${pkgdir}/etc/conf.d/sensord"
install -D -m644 "${srcdir}/healthd.service" "${pkgdir}/usr/lib/systemd/system/healthd.service"
install -D -m644 prog/init/*.service "${pkgdir}/usr/lib/systemd/system/"
}
|
