path: root/linux-libre-lts-6.10.14/PKGBUILD

# Maintainer: David P. <megver83@parabola.nu>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: fauno <fauno@parabola.nu>
# Contributor: Sorin-Mihai Vârgolici <smv@yobicore.org>
# Contributor: Michał Masłowski <mtjm@mtjm.eu>
# Contributor: Luke R. <g4jc@openmailbox.org>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# No official contributor: Enmanuel Eli <saravia@riseup.net>

# Based on linux package

_replacesarchkernel=('linux%') # '%' gets replaced with kernel suffix
_replacesoldkernels=() # '%' gets replaced with kernel suffix
_replacesoldmodules=() # '%' gets replaced with kernel suffix

_pkgbase=linux-libre
pkgbase=linux-libre-lts
_archpkgver=${_pkgver%-*}

_replacesarchkernel=('linux%') # '%' gets replaced with _kernelname
_replacesmainlinearchkernel=('linux%') # '%' gets replaced with _kernelname
_replacesoldkernels=() # '%' gets replaced with _kernelname
_replacesoldmodules=() # '%' gets replaced with _kernelname

_pkgbasever=6.10
_pkgver=${_pkgbasever}.14
pkgver=${_pkgbasever}.14
pkgrel=1
pkgdesc='Linux-libre'
url='https://linux-libre.fsfla.org/'
arch=(x86_64)
license=(GPL-2)
makedepends=(
	bc
	cpio
	gettext
	libelf
	dwarves
	perl
	python
	tar
	xz
	xmlto
	docbook-xsl
	kmod

	# htmldocs
	graphviz
	imagemagick
	python-sphinx
	# texlive-latexextra
)
options=('!strip')
_srcname=linux-$pkgver
source=(
	"https://linux-libre.fsfla.org/pub/linux-libre/releases/${_srcname##*-}-gnu/linux-libre-${_srcname##*-}-gnu.tar.xz"{,.sign}
	"https://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgver}-gnu/patch-${_pkgbasever}-gnu-${_pkgver}-gnu.lz"
	"https://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgver}-gnu/patch-${_pkgbasever}-gnu-${_pkgver}-gnu.lz.sign"
	"https://repo.parabola.nu/other/linux-libre/logos/logo_linux_"{clut224.ppm,vga16.ppm,mono.pbm}{,.sig}
	config.x86_64    # I have only x86_64
	linux.install
	linux.install.pkg
	linux.preset
	90-linux.hook
	# maintain the TTY over USB disconnects
	# http://www.coreboot.org/EHCI_Gadget_Debug
	0001-usb-serial-gadget-no-TTY-hangup-on-USB-disconnect-WI.patch
	# fix Atmel maXTouch touchscreen support
	# https://labs.parabola.nu/issues/877
	# http://www.fsfla.org/pipermail/linux-libre/2015-November/003202.html
	0002-fix-Atmel-maXTouch-touchscreen-support.patch
	# Arch Linux patches
	# https://github.com/archlinux/linux
	0001-ZEN-Add-sysctl-and-CONFIG-to-disallow-unprivileged-C.patch
	0003-arch-Kconfig-Default-to-maximum-amount-of-ASLR-bits.patch
)
validpgpkeys=(
	474402C8C582DAFBE389C427BCB7CF877E7D47A7  # Alexandre Oliva
	6DB9C4B4F0D8C0DC432CF6E4227CA7C556B2BA78  # David P.
)
sha256sums=('f03097b390de9573be11a43ff75478e28db91143658325690fc707174e9dcfba'
            'SKIP'
            '360b3a150f647f599c829ecebe360030ba81ec363c1d416f34473e959514173e'
            'SKIP'
            'bfd4a7f61febe63c880534dcb7c31c5b932dde6acf991810b41a939a93535494'
            'SKIP'
            '6de8a8319271809ffdb072b68d53d155eef12438e6d04ff06a5a4db82c34fa8a'
            'SKIP'
            '13bd7a8d9ed6b6bc971e4cd162262c5a20448a83796af39ce394d827b0e5de74'
            'SKIP'
            '78b1c0e0ba80bd6dcf2331effb8ee127fc7bd05e1027576ef72fcece209bc91a'
            '997dd1ca5c59e526a35d8367e6371a68406b1a58b90006e6f85d59a580c7503f'
            'a0b28c10eea009aa550a5b9a26c817496f6f7d04c17b307af0c15b7f482289ae'
            'ad6344badc91ad0630caacde83f7f9b97276f80d26a20619a87952be65492c65'
            'b61c6acd53eca29911c55bfeb8825a2fe7b0f30fe3547b1a1c609fb973c27482'
            '0376bd5efa31d4e2a9d52558777cebd9f0941df8e1adab916c868bf0c05f2fc3'
            '351fd96be8cd5ebd0435c0a8a978673fc023e3b1026085e67f86d815b2285e25'
            '994b27f23073a6e04bf8a61cd2eb9d2511b8eb0e81ed7828d4c3880f1e1f5061'
            'f36b1b3109d035139cfff75962a81c870fcb73fc3f81bb958e34a9e60af4fa3a')
b2sums=('45471cdf9e8fc37e384bdcfc2d22b113850daf62a5bea70a1dc6ea402fd2f924bc21cb0275f7e22532092e20af6de7fc2bc7f2056321d29fd29e5cb0e7e80f87'
	    'SKIP'
	    'e7e8c9e4bae48c6c15ce3d5b50694ae8560a48731263445c81284c5e798eb8d77ef032dc22d3dcbe8b47029f53518cbe559d8194b92d0c8bec76bb3acf9f708c'
	    'SKIP'
	    '73fee2ae5cb1ffd3e6584e56da86a8b1ff6c713aae54d77c0dab113890fc673dc5f300eb9ed93fb367b045ece8fa80304ff277fe61665eccf7b7ce24f0c045eb'
	    'SKIP'
	    'd02a1153a4285b32c774dca4560fe37907ccf30b8e487a681b717ed95ae9bed5988875c0a118938e5885ae9d2857e53a6f216b732b6fa3368e3c5fe08c86382c'
	    'SKIP'
	    '580911af9431c066bbc072fd22d5e2ef65f12d8358cec5ff5a4f1b7deebb86cef6b5c1ad631f42350af72c51d44d2093c71f761234fb224a8b9dbb3b64b8201d'
	    'SKIP'
	    '196423ae81a8c359db0c70888b3117d126594699ddbf3033c69c5c2aba02d20f7349a48b9d8095c7d398024b10ef1f89f12b59421074cd57ac74d9462b0457d0'
	    '6389814bc853747652d366753e69c007a7499ac62e0052c81f83b78f151a186b2b25409c5e08ee027e1a262767476b07d6812779056719a80caf70b7e1dd5621'
	    '5760e0879cf71dfc1c9bdd557829f28437909e701fa566cc3575a52785c81ac70d634ec929833ac01aea111bbae6ba402add738dc86623b32bcc3b523d43f60f'
	    'af69176b1117b94e56b043e97b0bd5873a2974a6a2fd52b102d0ffdca440ff68cfb241d6c4d4ef453cc8c220c236b739bad232e53fd500ce7672fa6e5ba87383'
	    '9336fb5d1f98a77144673750b0f924b15b60e98e4bba0d13d1b1a5c977f14538f97143147081c94e0d8555b5dbd246fe0a410c7146a9b0866f3728176548fb0a'
	    'eeed12b2ab60c3d3aad598a1d44b4f23560d818e8fe1ef143f857c8e176652df53501b192ade7d4d915d425fff818b2a232d46bae0d3a0f46b8959e614e0ede2'
	    'aaa4e28a31967cc3a7fe25a86ba35fdfa210cd8b1a9cc96298349cbf01d60cdf146ee519d6803d05b175873f1b3367e47194a178db7ed97c802e59b38f8c303c'
	    'c2214154c36900e311531bfe68184f31639f5c50fed23bc3803a7f18439b7ff258552a39f02fed0ea92f10744e17a6c55cef0ef1a98187f978fe480fb3dddc14'
	    '0c7ceba7cd90087db3296610a07886f337910bad265a32c052d3a703e6eb8e53f355ab9948d72d366408d968d8ee7435084dd89bef5ed0b69355fd884c2cd468'
	    '6f1d4a50cbfc5777d481596593b4d137fcd35b5b2af6ad610147ae28e5918800f917f7d65544c97b67005ad7c171b36c205c748e24a5d44fea23ed53460bd2bc'
	    '3b9a9e60af14d82d82e9645b55cd8f1f5827da1b15226c1cd8022c0a426c1d4d66981c2be2ef422cd7401aa74d3e610ebe9f4e76e0b506cebe758bc27464145a'
	    'a8b01480b16f062bf465149494387f6f4eabc3289dc7596c4dbfe4a4a963f60d717f86cead9dc37d1fea9c9213cd6d2663648f3fc8d197c09d006ac2dc0c4511')

_replacesarchkernel=("${_replacesarchkernel[@]/\%/${pkgbase#linux-libre}}")
_replacesoldkernels=("${_replacesoldkernels[@]/\%/${pkgbase#linux-libre}}")
_replacesoldmodules=("${_replacesoldmodules[@]/\%/${pkgbase#linux-libre}}")

case "$CARCH" in
	i686|x86_64) KARCH=x86;;
esac

export KBUILD_BUILD_HOST=hyperbola
export KBUILD_BUILD_USER=$pkgbase
export KBUILD_BUILD_TIMESTAMP="$(date -Ru${SOURCE_DATE_EPOCH:+d @$SOURCE_DATE_EPOCH})"

prepare() {
	cd "${srcdir}/linux-${pkgver}"

	echo "Adding freedo as boot logo..."
	install -m644 -t drivers/video/logo \
			../logo_linux_{clut224.ppm,vga16.ppm,mono.pbm}

	echo "Setting version..."
	echo "-$pkgrel" > localversion.10-pkgrel
	echo "${pkgbase#linux-libre}" > localversion.20-pkgname

	local source=("${source[@]}")

	local src
	for src in "${source[@]}"; do
	    src="${src%%::*}"
	    src="${src##*/}"
	    src="${src%.zst}"
	    [[ $src = *.patch ]] || continue
	    echo "Applying patch $src..."
	    patch -p1 -i "${srcdir}/$src"
	done

	echo "Setting config..."
	cp ../config.$CARCH .config
	yes "" | make olddefconfig
	diff -u ../config.$CARCH .config || :

	yes "" | make -s kernelrelease > version
	echo "Prepared $pkgbase version $(<version)"
	echo "!enma $(pwd) prepare"
}

build() {
	echo "!enma $(pwd) build"
	cd "${srcdir}/linux-${pkgver}"
	make ${MAKEFLAGS} LOCALVERSION= bzImage modules
}

_package() {
	pkgdesc="The ${pkgbase^} kernel and modules"
	[ "${pkgbase}" = "linux-libre-lts" ] && groups=('base')
	depends=('coreutils' 'kmod' 'mkinitcpio>=0.7')
	optdepends=('kernel-firmware: firmware files for Linux-libre'
	            'crda: to set the correct wireless channels of your country')
	provides=("${_replacesarchkernel[@]/%/=${_archpkgver}}" "${_replacesoldkernels[@]}" "kernel=${_archpkgver}" "${_replacesmainlinearchkernel[@]}")
	conflicts=("${_replacesarchkernel[@]}" "${_replacesoldkernels[@]}" "${_replacesoldmodules[@]}" "${_replacesmainlinearchkernel[@]}")
	replaces=("${_replacesarchkernel[@]}" "${_replacesoldkernels[@]}" "${_replacesoldmodules[@]}" "${_replacesmainlinearchkernel[@]}")
	backup=("etc/mkinitcpio.d/${pkgbase}.preset")
	install=linux.install

	cd "${srcdir}/linux-${_pkgver}"

	# get kernel version
	_kernver="$(make LOCALVERSION= kernelrelease)"
	_basekernel=${_kernver%%-*}
	_basekernel=${_basekernel%.*}

	mkdir -p "${pkgdir}"/{lib/modules,lib/firmware,boot}
	install -Dm644 arch/$KARCH/boot/bzImage "${pkgdir}/boot/vmlinuz-${pkgbase}"
	make ${MAKEFLAGS} LOCALVERSION= INSTALL_MOD_PATH="${pkgdir}" INSTALL_MOD_STRIP=1 modules_install

	# set correct depmod command for install
	sed -e "s|%PKGBASE%|${pkgbase}|g;s|%KERNVER%|${_kernver}|g" \
	    "${startdir}/${install}" > "${startdir}/${install}.pkg"
	true && install=${install}.pkg

	# install mkinitcpio preset file for kernel
	sed "s|%PKGBASE%|${pkgbase}|g" "${srcdir}/linux.preset" |
	    install -D -m644 /dev/stdin "${pkgdir}/etc/mkinitcpio.d/${pkgbase}.preset"

	# install pacman hook for initramfs regeneration
	sed "s|%PKGBASE%|${pkgbase}|g" "${srcdir}/90-linux.hook" |
	    install -D -m644 /dev/stdin "${pkgdir}/usr/share/libalpm/hooks/90-${pkgbase}.hook"

	# remove build and source links
	rm -f "${pkgdir}"/lib/modules/${_kernver}/{source,build}

	# # remove the firmware
	# rm -rf "${pkgdir}/lib/firmware"

	# make room for external modules
	ln -s "../extramodules-${_basekernel}${_kernelname}" "${pkgdir}/lib/modules/${_kernver}/extramodules"
	# add real version for building modules and running depmod from post_install/upgrade
	mkdir -p "${pkgdir}/lib/modules/extramodules-${_basekernel}${_kernelname}"
	echo "${_kernver}" > "${pkgdir}/lib/modules/extramodules-${_basekernel}${_kernelname}/version"

	# Now we call depmod...
	depmod -b "${pkgdir}" -F System.map "${_kernver}"

	# add kernel configuration file
	# https://issues.hyperbola.info/index.php?do=details&task_id=146
	install -D -m644 .config "${pkgdir}/boot/config-${pkgbase}"

	# install license file
	install -D -m644 COPYING "${pkgdir}/usr/share/licenses/$pkgname/COPYING"
}

_package-headers() {
	pkgdesc="Header files and scripts for building modules for ${pkgbase^} kernel"
	provides=("${_replacesarchkernel[@]/%/-headers=${_archpkgver}}" "${_replacesoldkernels[@]/%/-headers}" "${_replacesmainlinearchkernel[@]/%/-headers}")
	conflicts=("${_replacesarchkernel[@]/%/-headers}" "${_replacesoldkernels[@]/%/-headers}" "${_replacesmainlinearchkernel[@]/%/-headers}")
	replaces=("${_replacesarchkernel[@]/%/-headers}" "${_replacesoldkernels[@]/%/-headers}" "${_replacesmainlinearchkernel[@]/%/-headers}")

	install -dm755 "${pkgdir}/lib/modules/${_kernver}"

	cd "${srcdir}/linux-${_pkgver}"
	install -D -m644 Makefile \
		    "${pkgdir}/lib/modules/${_kernver}/build/Makefile"
	install -D -m644 kernel/Makefile \
		    "${pkgdir}/lib/modules/${_kernver}/build/kernel/Makefile"
	install -D -m644 .config \
		    "${pkgdir}/lib/modules/${_kernver}/build/.config"
	install -D -m644 vmlinux \
		    "${pkgdir}/lib/modules/${_kernver}/build/vmlinux"
	install -D -m644 System.map \
		    "${pkgdir}/lib/modules/${_kernver}/build/System.map"
	install -D -m644 Module.symvers \
		    "${pkgdir}/lib/modules/${_kernver}/build/Module.symvers"

	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/include"

	for i in acpi asm-generic clocksource config crypto drm dt-bindings \
				  generated keys kunit kvm linux math-emu media memory misc net \
				  pcmcia ras rdma scsi soc sound target trace uapi vdso video xen; do
		cp -a include/${i} "${pkgdir}/lib/modules/${_kernver}/build/include/"
	done

	# copy arch includes for external modules
	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/arch/${KARCH}"
	cp -a arch/${KARCH}/include "${pkgdir}/lib/modules/${_kernver}/build/arch/${KARCH}/"

	# copy files necessary for later builds
	cp -a scripts "${pkgdir}/lib/modules/${_kernver}/build"

	# fix permissions on scripts dir
	chmod og-w -R "${pkgdir}/lib/modules/${_kernver}/build/scripts"
	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/.tmp_versions"

	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/arch/${KARCH}/kernel"

	cp arch/${KARCH}/Makefile "${pkgdir}/lib/modules/${_kernver}/build/arch/${KARCH}/"

	cp arch/${KARCH}/kernel/asm-offsets.s "${pkgdir}/lib/modules/${_kernver}/build/arch/${KARCH}/kernel/"

	# add dm headers
	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/drivers/md"
	cp drivers/md/*.h "${pkgdir}/lib/modules/${_kernver}/build/drivers/md"

	# add inotify.h
	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/include/linux"
	cp include/linux/inotify.h "${pkgdir}/lib/modules/${_kernver}/build/include/linux/"

	# add wireless headers
	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/net/mac80211/"
	cp net/mac80211/*.h "${pkgdir}/lib/modules/${_kernver}/build/net/mac80211/"

	# add dvb headers for external modules
	# http://bugs.archlinux.org/task/11194
	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/include/config/dvb/"
	cp include/uapi/linux/dvb/*.h "${pkgdir}/lib/modules/${_kernver}/build/include/config/dvb/"

	# add dvb headers for http://mcentral.de/hg/~mrec/em28xx-new
	# in reference to:
	# http://bugs.archlinux.org/task/13146
	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/dvb-frontends/"
	cp drivers/media/dvb-frontends/lgdt330x.h "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/dvb-frontends/"
	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/i2c/"
	cp drivers/media/i2c/msp3400-driver.h "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/i2c/"

	# add dvb headers
	# in reference to:
	# http://bugs.archlinux.org/task/20402
	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/usb/dvb-usb"
	cp drivers/media/usb/dvb-usb/*.h "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/usb/dvb-usb/"
	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/dvb-frontends"
	cp drivers/media/dvb-frontends/*.h "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/dvb-frontends/"
	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/tuners"
	cp drivers/media/tuners/*.h "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/tuners/"

	# add xfs and shmem for aufs building
	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/fs/xfs"
	mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/mm"
	# removed in 3.17-gnu series
	# cp fs/xfs/xfs_sb.h "${pkgdir}/lib/modules/${_kernver}/build/fs/xfs/xfs_sb.h"

	# copy in Kconfig files
	for i in $(find . -name "Kconfig*"); do
		mkdir -p "${pkgdir}"/lib/modules/${_kernver}/build/`echo ${i} | sed 's|/Kconfig.*||'`
		cp ${i} "${pkgdir}/lib/modules/${_kernver}/build/${i}"
	done

	# add objtool for external module building and enabled VALIDATION_STACK option
	if [ -f tools/objtool/objtool ];  then
		mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/tools/objtool"
		cp -a tools/objtool/objtool ${pkgdir}/lib/modules/${_kernver}/build/tools/objtool/
	fi

	chown -R root.root "${pkgdir}/lib/modules/${_kernver}/build"
	find "${pkgdir}/lib/modules/${_kernver}/build" -type d -exec chmod 755 {} \;

	# strip scripts directory
	find "${pkgdir}/lib/modules/${_kernver}/build/scripts" -type f -perm -u+w 2>/dev/null | while read binary ; do
		case "$(file -bi "${binary}")" in
		    *application/x-sharedlib*) # Libraries (.so)
		        /usr/bin/strip ${STRIP_SHARED} "${binary}";;
		    *application/x-archive*) # Libraries (.a)
		        /usr/bin/strip ${STRIP_STATIC} "${binary}";;
		    *application/x-executable*) # Binaries
		        /usr/bin/strip ${STRIP_BINARIES} "${binary}";;
		    *application/x-pie-executable\;*) # Relocatable binaries
		        /usr/bin/strip ${$STRIP_SHARED} "${binary}";;
		esac
	done

	# strip vmlinux
	strip -v $STRIP_STATIC "${pkgdir}/lib/modules/${_kernver}/build/vmlinux"

	# remove unneeded architectures
	find "${pkgdir}"/lib/modules/${_kernver}/build/arch -mindepth 1 -maxdepth 1 -type d -not -name "$KARCH" -exec rm -rf {} +

	# remove documentation
	rm -r "${pkgdir}/lib/modules/${_kernver}/build/Documentation"

	# remove broken symlinks
	find -L "${pkgdir}/lib/modules/${_kernver}/build" -type l -printf 'Removing %P\n' -delete

	# remove loose objects
	find "${pkgdir}/lib/modules/${_kernver}/build" -type f -name '*.o' -printf 'Removing %P\n' -delete

	# add symlink
	mkdir -p "$pkgdir/usr/src"
	ln -sr "${pkgdir}/lib/modules/${_kernver}/build" "$pkgdir/usr/src/$pkgbase"

	# install license file
	install -D -m644 COPYING "${pkgdir}/usr/share/licenses/$pkgname/COPYING"
}

pkgname=(
	"$pkgbase"
	"$pkgbase-headers"
	# "$pkgbase-docs"
)

for _p in "${pkgname[@]}"; do
	eval "package_$_p() {
	    $(declare -f "_package${_p#$pkgbase}")
	    _package${_p#$pkgbase}
	  }"
done

# vim:set ts=8 sts=2 sw=2 et: