blob: 24ab0d642808703432bb4326e87b536c1a3d66f4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer (Arch): Gaetan Bisson <bisson@archlinux.org>
# Contributor (Arch): Ashish Shukla <wahjava.ml@gmail.com>
# Contributor: Jesús E. <heckyel@hyperbola.info>
pkgname=libotf
pkgver=0.9.13
_debver=0.9.13
_debrel=7
pkgrel=0
pkgdesc='OpenType Font library'
url='https://www.nongnu.org/m17n/'
license=('LGPL-2.1')
arch=('i686' 'x86_64')
depends=('libxaw' 'freetype2')
makedepends=('quilt')
source=("https://download.savannah.gnu.org/releases/m17n/${pkgname}-${pkgver}.tar.gz"
"https://deb.debian.org/debian/pool/main/libo/libotf/libotf_$_debver-$_debrel.debian.tar.xz")
sha512sums=('86ddf071df371ee44910afc02432352356bfa1c2a55b44274c95fc4e7ec4fca982a7fcde35aaa63a8cb332e98388a9faf9a94fbf0f39e85668630f77d841ef31'
'93b3d35d33f42814fc2ba5ca4bcb8412938c49065f17c5fd207068108b92fa6095f8df7ca149a17f2ce5a700dffb02fa90515de226fde6858d8611de61014b81')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
# Debian patches
export QUILT_PATCHES=debian/patches
export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
export QUILT_DIFF_ARGS='--no-timestamps'
mv "$srcdir"/debian .
# Doesn't apply and seems unimportant
rm -v debian/patches/0001-libotf-config-modify-to-support-multi-arch.patch || true
quilt push -av
fi
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
autoreconf -i
./configure --prefix=/usr
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -d "$pkgdir/usr/share/licenses/$pkgname"
install -m644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
# vim:set ts=2 sw=2 et:
|
