blob: 439ddaae482a0c4d7210da60988d76005f0333bc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer (Arch): Andreas Radke <andyrtr@archlinux.org>
# Maintainer (Arch): Jan de Groot
# Maintainer: André Silva <emulatorman@hyperbola.info>
pkgname=libinput
pkgver=1.7.2
pkgrel=1.hyperbola2
pkgdesc="Input device management and event handling library, without systemd support"
arch=(i686 x86_64)
url="https://www.freedesktop.org/wiki/Software/libinput/"
license=(Expat)
depends=('mtdev' 'libevdev' 'libwacom')
# currently no doc files to install
makedepends=('doxygen' 'graphviz' 'gtk3')
#checkdepends=('check' 'libunwind')
source=(https://freedesktop.org/software/$pkgname/$pkgname-$pkgver.tar.xz{,.sig})
sha512sums=('cdbd2994e954aac9538fe907c275e6e23e2bed0e9c4c65f19591bdcdbf5074131c72b92e87de87c03f75a991fcdb7f568b491a12f00031c4eba11082ca44d69f'
'SKIP')
validpgpkeys=('3C2C43D9447D5938EF4551EBE23B7E70B467F0BF') # Peter Hutterer (Who-T) <office@who-t.net>
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr --disable-static
make
}
check() {
cd $pkgname-$pkgver
make check
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
# move udev to /lib for FHS compliance
install -dm755 ${pkgdir}/lib
mv ${pkgdir}/usr/lib/udev ${pkgdir}/lib
# install doc - no Makefile target
install -v -dm755 ${pkgdir}/usr/share/doc/libinput
cp -rv doc/html/* ${pkgdir}/usr/share/doc/libinput
}
|
