1 files changed, 59 insertions, 0 deletions
diff --git a/gtest/PKGBUILD b/gtest/PKGBUILD
new file mode 100644
index 0000000..fc5a2b6
--- /dev/null
+++ b/gtest/PKGBUILD
@@ -0,0 +1,59 @@
+# Maintainer: Cory Sanin <corysanin@artixlinux.org>
+# Contributor: Carl Smedstad <carsme@archlinux.org>
+# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Felix Yan <felixonmars@archlinux.org>
+# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Contributor: Alexandre Bique <bique.alexandre@gmail.com>
+# Contributor: Louis R. Marascio <lrm@fitnr.com>
+# Contributor: Cody Maloney <cmaloney@theoreticalchaos.com>
+# Contributor: acxz <akashpatel2008 at yahoo dot com>
+
+pkgname=gtest
+pkgver=1.17.0
+pkgrel=1
+pkgdesc='Google Test - C++ testing utility'
+url='https://github.com/google/googletest'
+arch=('x86_64')
+license=('BSD-3-Clause')
+depends=(
+  'gcc-libs'
+  'glibc'
+)
+makedepends=(
+  'cmake'
+  'python'
+)
+optdepends=('python: gmock generator')
+conflicts=('gmock')
+replaces=('gmock')
+provides=(
+  'gmock'
+  'libgmock.so'
+  'libgmock_main.so'
+  'libgtest.so'
+  'libgtest_main.so'
+)
+_srcname=googletest-${pkgver}
+source=("${_srcname}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
+sha512sums=('0f57e9ef06925e5b7722df1eb92ef5850e8dce79220ea16a8aaff586a71c0b01460ef1713649ee24ffedb2e6ad5a51e9198c5a5ae1b2789e43feb1f494e7d45c')
+
+build() {
+ cmake -H${_srcname} -Bbuild \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=None \
+    -Wno-dev \
+    -DBUILD_SHARED_LIBS=ON \
+    -Dgtest_build_tests=ON \
+    -DGOOGLETEST_VERSION=$pkgver
+  cmake --build build
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --install build
+
+  cd ${_srcname}
+  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -vDm 644 README.md CONTRIBUTORS -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: