1 files changed, 50 insertions, 0 deletions
diff --git a/aardvark-dns/PKGBUILD b/aardvark-dns/PKGBUILD
new file mode 100644
index 0000000..db1df52
--- /dev/null
+++ b/aardvark-dns/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: David Runge <dvzrv@archlinux.org>
+# Maintainer: Morten Linderud <foxboron@archlinux.org>
+
+pkgname=aardvark-dns
+pkgver=1.14.0
+pkgrel=1
+pkgdesc="Authoritative dns server for A/AAAA container records"
+arch=(x86_64)
+url="https://github.com/containers/aardvark-dns"
+license=(Apache-2.0)
+depends=(
+  git-legacy
+  glibc
+)
+makedepends=(
+  rust-bin
+  git-legacy
+  libgit2
+)
+source=(https://github.com/containers/aardvark-dns/archive/refs/tags/v${pkgver}.tar.gz)
+sha512sums=('0300c474bb748063bf96488c06920df15ade525a8ee288446d3f30c3cffdccd687744efbb76e54a6b2213c38c02b00400ad79459bd78e8721556ff8dcdc1df8e')
+# NOTE: pinning commit until upstream clarifies commitment to chain of trust:
+# https://github.com/containers/aardvark-dns/issues/83
+# validpgpkeys=('74FE091D25519980B2D84447160386BECB6F0643')  # Brent Baude <bbaude@redhat.com>
+
+prepare() {
+  cd $pkgname-$pkgver
+  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+
+  cd $pkgname-$pkgver
+  cargo build --frozen --release --all-features
+}
+
+check() {
+  export RUSTUP_TOOLCHAIN=stable
+
+  cd $pkgname-$pkgver
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd $pkgname-$pkgver
+  install -vDm 755 target/release/$pkgname -t "$pkgdir/usr/lib/podman/"
+  install -vDm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}