First commitdevelop

1 files changed, 46 insertions, 0 deletions

diff --git a/python-filelock/PKGBUILD b/python-filelock/PKGBUILD
new file mode 100644
index 0000000..2f385c3
--- /dev/null
+++ b/python-filelock/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
+# Maintainer: Tobias Dausend <throgh@hyperbola.info>
+# Contributor: rachad
+
+_pkgname=filelock
+pkgbase=python-filelock
+pkgname=('python-filelock' 'tauthon-filelock')
+pkgver=3.0.12
+pkgrel=2
+pkgdesc="A platform independent file lock"
+url='https://github.com/benediktschmitt/py-filelock'
+license=('Public-Domain')
+arch=('any')
+makedepends=('python-setuptools' 'tauthon-setuptools')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/benediktschmitt/py-filelock/archive/v$pkgver.tar.gz")
+sha512sums=('2e8bcf4a0b637ab9b6c031e2b49d75c8ffb03d5666d8865a4f097acf978f3aa7c260f973efd41e958a60ad938883d8b4d47f5ee9ba1ca4c8be1c295d17faf212')
+
+prepare() {
+  cp -a $_pkgname-$pkgver{,-tauthon}
+}
+
+build() {
+  cd "$srcdir/$_pkgname-$pkgver"
+  python setup.py build
+
+  cd "$srcdir/$_pkgname-$pkgver-tauthon"
+  tauthon setup.py build
+}
+
+package_python-filelock() {
+  pkgdesc+=" for Python"
+  depends=('python')
+
+  cd "$srcdir/$_pkgname-$pkgver"
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}
+
+package_tauthon-filelock() {
+  pkgdesc+=" for Tauthon"
+  depends=('tauthon')
+
+  cd "$srcdir/$_pkgname-$pkgver-tauthon"
+  tauthon setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}