# Maintainer (Arch): Konstantin Gizdov <arch at kge dot pw>
# Contributor (Arch): Yusuf Aktepe <yusuf@yusufaktepe.com>
# Contributor (Arch): Florian Pritz <bluewind@xinu.at>
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor (Arch): Thayer Williams <thayer@archlinux.org>
# Maintainer: Tobias Dausend <throgh@hyperbola.info>

pkgname=xbindkeys
pkgver=1.8.7
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="Launch shell commands with your keyboard or your mouse under X"
arch=('i686' 'x86_64')
url='https://www.nongnu.org/xbindkeys/xbindkeys.html'
license=('GPL-2')
depends=('libx11' 'guile')
makedepends=('quilt')
optdepends=('tk: for xbindkeys_show')
source=("https://www.nongnu.org/${pkgname}/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/x/xbindkeys/xbindkeys_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('a6b1478e8ef4bedc686fdd15abc11a8a592ac17c69e1a5a13f60e735e9be9646faed62e980cdac4aa7bc7e3253237465de38dee98935dd3f9911d4e48209b2e9'
            '00fc2d906ea8f6be58efbb6fb2e115f913ccab39523125cbc40f6defacc63a262687d83343033324c3a13d82a88983839f41803b24443e8095e69d94bf02e37b')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # pick up new guile versions
  autoreconf -vi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}