# Maintainer (Arch): Dan McGee <dan@archlinux.org>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Daniele Paolella <dp@mcrservice.it>
# Maintainer: Tobias Dausend <throgh@hyperbola.info>
# Contributor: Jesús E.
# Contributor: rachad

pkgname=python-virtualenv
pkgver=20.7.1
pkgrel=5
pkgdesc="Virtual Python Environment builder"
url='https://virtualenv.pypa.io/'
arch=('any')
license=('Expat')
depends=('python-platformdirs' 'python-distlib' 'python-filelock' 'python-six' 'python-importlib-metadata')
makedepends=('python-setuptools' 'python-setuptools-scm' 'python-sphinx' 'python-sphinx_rtd_theme'
             'python-sphinx-argparse' 'towncrier')
replaces=('virtualenv')
conflicts=('virtualenv')
options=('!makeflags')
source=(https://github.com/pypa/virtualenv/archive/$pkgver/$pkgname-$pkgver.tar.gz)
sha512sums=('6ab88145c0d9b3b7d8eef37fcfa2608d1e3a3a17dec9b6d00f0b90c7d2c31faad22a2fb04cda0cd1b1ecc9140b6dc555f38ab1690ffe94ea1cd441b4ad9879ed')

export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver

prepare() {
  sed -i '/test_py_info_to_system_raises/i @pytest.mark.skip' virtualenv-$pkgver/tests/unit/discovery/py_info/test_py_info.py

  # workaround pip vendorod certifi
  sed -i "s|pkgutil.get_data(\"pip._vendor.certifi\", \"cacert.pem\")|open(os.path.join('/etc/ssl/certs/ca-certificates.crt'), 'rb').read()|" virtualenv-$pkgver/tests/conftest.py

  # fix platformdirs
  sed -i "s|platformdirs>=2,<3|platformdirs|g" virtualenv-$pkgver/setup.cfg

  # use importlib-metadata directly for Python
  sed -i 's/from backports.entry_points_selectable import entry_points/from importlib_metadata import entry_points/' virtualenv-$pkgver/src/virtualenv/run/plugin/base.py
  sed -i '/backports.entry_points_selectable/d' virtualenv-$pkgver/setup.cfg
}

build() {
  cd virtualenv-$pkgver
  python setup.py build egg_info
  export PYTHONPATH="$PWD/build/lib:$PWD/src"
  sphinx-build -b man docs docs/_build/man
}

package() {
  cd virtualenv-$pkgver
  python setup.py install --prefix=/usr --root="$pkgdir" --skip-build
  install -Dm644 docs/_build/man/virtualenv.1 "${pkgdir}/usr/share/man/man1/virtualenv.1"
  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
}