# Maintainer (Arch): LibreUser. <name@domain.com>
# Maintainer (Arch): Gaetan Bisson <bisson@archlinux.org>
# Contributor (Arch): damir <damir@archlinux.org>
# Contributor (Arch): Camille Moncelier <pix@devlife.org>
# Contributor: Jesús E. <heckyel@hyperbola.info>

pkgname=m17n-db
pkgver=1.8.0
_debver=1.8.0
_debrel=3
pkgrel=0
pkgdesc='Multilingual text processing library (database)'
url='https://www.nongnu.org/m17n/'
arch=('any')
license=('LGPL-2.1')
depends=('glibc')
makedepends=('quilt')
source=("https://download.savannah.gnu.org/releases/m17n/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/m/m17n-db/m17n-db_$_debver-$_debrel.debian.tar.xz"
        '0001-fix-warnings-gawk.patch')
sha512sums=('b21abfdcb5eb42e71fbd5edd1a99eca4a05df14f5a57eac7cdd3dc657337bd143a419f4b3f3dd0b74b82c827ede4d3666dd213af9041593cef50118ee43898d5'
            '96e0992c9b58ef4578473f54c8b945dd631a04b507eb918490d3dd9b0e22e2d22e81f415d80b97f94d507fb589cdeeeac912cb80771343deb43175bb61adce88'
            '4f04d22290d5c81e076cc663e49fdb8a8f554fd20e68b3a9752092a6be21cc9b6413f7e6a55760d4d134d7862d1de2b43025d9de1d19f1efb8d57bf347fc6c75')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  patch -Np1 -i ${srcdir}/0001-fix-warnings-gawk.patch
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install

  # Drop script that makes UIM segfault http://savannah.nongnu.org/bugs/index.php?53202
  rm "$pkgdir"/usr/share/m17n/hu-rovas-post.mim

  install -d "$pkgdir/usr/share/licenses/$pkgname"
  install -m644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}

# vim:set ts=2 sw=2 et: