# Maintainer: 31337h4ck3r at gmail dot com
# Contributor: katt <magunasu.b97@gmail.com>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Stefano Zamprogno <stefano dot zamprogno at gmail dot com>
# Contributor: Chuck Yang <Chuck.Yang@gmail.com>
pkgname=lshw
pkgver=B.02.20
pkgrel=1
pkgdesc='A small tool to provide detailed information on the hardware configuration of the machine'
url=https://ezix.org/project/wiki/HardwareLiSter
license=(GPL)
arch=(x86_64)
depends=(gcc-libs hwdata)
optdepends=('gtk3: for gtk-lshw')
makedepends=(gtk3 sqlite gettext) # Removed docbook-utils and perl-sgmls
conflicts=("lshw")
provides=("lshw")
source=(https://ezix.org/src/pkg/${pkgname}/archive/${pkgver}.tar.gz)
sha512sums=('af0764aa86e3ab9e79e98fe362e3411c5f59da7e52a3959e090c1da2d3ce7e22ac049081b5e2c87f4dfce45dbc009f3c0f77108d655cfab01626ac5f0ad35cbd')
prepare() {
 cd ${pkgname}
 sed -i 's|/usr/bin/gtk-lshw|/usr/sbin/gtk-lshw|' src/gui/integration/gtk-lshw.desktop
 sed -i '/^LDFLAGS=$/d' src/core/Makefile src/gui/Makefile
}
build() {
 cd ${pkgname}
 export VERSION=$pkgver
 make SBINDIR=/usr/bin
 make SBINDIR=/usr/bin gui
}
package() {
 cd ${pkgname}
 make DESTDIR="$pkgdir"/ SBINDIR=/usr/bin install
 make DESTDIR="$pkgdir"/ SBINDIR=/usr/bin install-gui
 install -Dm0644 src/gui/integration/gtk-lshw.desktop -t "$pkgdir"/usr/share/applications
 rm -f "$pkgdir"/usr/share/lshw/{pci,usb}.ids
}