# Maintainer: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: Luke R. <g4jc@hyperbola.info>
# Contributor: Jesús E. <heckyel@hyperbola.info>
# Contributor: rachad <rachad @ hyperbola . info>
# Contributor (Parabola): Nicolás Reynolds <fauno@kiwwwi.com.ar>
# Contributor (Parabola): Sorin-Mihai Vârgolici <smv@yobicore.org>
# Contributor (Parabola): Michał Masłowski <mtjm@mtjm.eu>
# Contributor (Parabola): Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor (Parabola): David P. <megver83@parabola.nu>
# Contributor (Parabola): Andreas Grapentin <andreas@grapentin.org>

# Based on linux-lts package

pkgbase=linux-libre-lts
_pkgbasever=5.15
_pkgver=5.15.170

_replacesarchkernel=('linux%') # '%' gets replaced with _kernelname
_replacesmainlinearchkernel=('linux%') # '%' gets replaced with _kernelname
_replacesoldkernels=() # '%' gets replaced with _kernelname
_replacesoldmodules=() # '%' gets replaced with _kernelname

_srcname=linux-${_pkgbasever%-*}
_archpkgver=${_pkgver%-*}
pkgver=${_pkgver//-/_}
pkgrel=1
arch=('i686' 'x86_64')
url="https://linux-libre.fsfla.org/"
license=('GPL-2')
makedepends=('xmlto' 'docbook-xsl' 'kmod' 'bc' 'libelf' 'python' 'cpio' 'dwarves')
options=('!strip')
source=(https://cdn.kernel.org/pub/linux/kernel/v5.x/linux-5.15.170.tar.xz
        https://cdn.kernel.org/pub/linux/kernel/v5.x/linux-5.15.170.tar.sign
        https://cdn.kernel.org/pub/linux/kernel/v5.x/patch-5.15.170.xz
        # "https://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgbasever}/linux-libre-${_pkgbasever}.tar.lz"
        # "https://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgbasever}/linux-libre-${_pkgbasever}.tar.lz.sign"
        # "https://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgver}/patch-${_pkgbasever}-${_pkgver}.lz"
        # "https://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgver}/patch-${_pkgbasever}-${_pkgver}.lz.sign"
        "https://git.hyperbola.info:50100/culture/linux-libre_logos.git/plain/logo_linux_clut224.ppm"
        # "https://git.hyperbola.info:50100/culture/linux-libre_logos.git/plain/logo_linux_clut224.ppm.sig"
        "https://git.hyperbola.info:50100/culture/linux-libre_logos.git/plain/logo_linux_mono.pbm"
        # "https://git.hyperbola.info:50100/culture/linux-libre_logos.git/plain/logo_linux_mono.pbm.sig"
        "https://git.hyperbola.info:50100/culture/linux-libre_logos.git/plain/logo_linux_vga16.ppm"
        # "https://git.hyperbola.info:50100/culture/linux-libre_logos.git/plain/logo_linux_vga16.ppm.sig"
        # the main kernel config files: generated by copying it to .config in kernel tree:
        ## ARCH=i386 make oldconfig
        'config.i686'
        ## ARCH=x86_64 make oldconfig
        'config.x86_64'
        # pacman hook for initramfs regeneration
        '90-linux.hook'
        # standard config files for mkinitcpio ramdisk
        'linux.preset'
        '0001-ZEN-Add-sysctl-and-CONFIG-to-disallow-unprivileged-C.patch'
        '0002-usb-serial-gadget-no-TTY-hangup-on-USB-disconnect-WI.patch'
        '0003-fix-Atmel-maXTouch-touchscreen-support.patch'
        '0004-HID-quirks-Add-Apple-Magic-Trackpad-2-to-hid_have_sp.patch'
        '0006-v2-kbuild-support-byacc-as-alternative-YACC-to-bison.patch'
        '0007-sign-file-full-functionality-with-modern-LibreSSL.patch')
sha512sums=('521a3b178f6979f7259ff46aa42722b07fa716d7883c617729972a78b23737be6538827263aad998f58485763f6ddb58d80ff769ab1447825dd870cf2744f038'
            'SKIP'
            '5088ee4103304abaeadf0145c2a4e2380bb1264d2a81d733bac7ffe30eb8a83727f278b3e0598bd0ef3d95141f28552f01e7dbf0567fc406e51f62809049b00d'
            '13cb5bc42542e7b8bb104d5f68253f6609e463b6799800418af33eb0272cc269aaa36163c3e6f0aacbdaaa1d05e2827a4a7c4a08a029238439ed08b89c564bb3'
            '267295aa0cea65684968420c68b32f1a66a22d018b9d2b2c1ef14267bcf4cb68aaf7099d073cbfefe6c25c8608bdcbbd45f7ac8893fdcecbf1e621abdfe9ecc1'
            '7a3716bfe3b9f546da309c7492f3e08f8f506813afeb1c737a474c83313d5c313cf4582b65215c2cfce3b74d9d1021c96e8badafe8f6e5b01fe28d2b5c61ae78'
            'e1f415942cc2e603ce8d9acf09ca23814be100d93f13aeffa23b263adee4eee313885d830c1cf7179ffd80ea73ef8cd73850658dae98d5396194bfed104e80ca'
            '12c10c014ec1919e0fbc5297bb0eca06d4e1b9639d54843a7c254ae846f381510f87f90e68d1a9c75a53ef23e4ec95cbca91d1ff0cc93eadffd1883893336550'
            '38ddc517f33fe41dec63b31313a82e0e8c05788e9db5e448d23a01605c50fe3422927cfd902e81c3b0eae17502db06f48e7f713e1ba1c9c76fd26f1473b02983'
            '2dc6b0ba8f7dbf19d2446c5c5f1823587de89f4e28e9595937dd51a87755099656f2acec50e3e2546ea633ad1bfd1c722e0c2b91eef1d609103d8abdc0a7cbaf'
            'c4507794fa2e01026d0179171865a2352fc56b32af25123c2627ecd444663ebf00d0080c12821ba73e1ddb7ded852cebdd7329e3997321f41c169d2367718037'
            '4d7388cb03b873f4c360d345dd20b04f9e5ac815183e8ae588f8bdadab2056d6d8f21ae0dd2055ea32bb59364e2d41b9272276abd532a00b8cc89278f8bf409f'
            '5bdb620acf90799b78dea3fd07828c2dc4410f781af47e910c725bd3c8e5ff4695d06e9ab7e59afaa0e759c77917e66e3e2c5f6dd9d4ac59f2a66109adf06cac'
            'd6dadc6a563af83e588c67fc11cc40952a43f5bca0cb53cc3990430ce1944cd29df4526a1a34c2def7e44cf3f5d2202a719d18117ce6acaeadd0a9b10968270d'
            '57f7cf2356a1e78d58298c638987882b43c23e06ab31d6f7284f5d8e2f59781e1fe42f091943c82b3d3b53d13a9cfaf5e6ee460d6ece0613f734404da57a1147'
            '9296c41fab18b2b2ed6a1483061c0012673abf041792ad826d3530a1e837cf82a59e507ada5e05f31be3f780409d5b2defd0bf82de058b92856ada14b243b033')
validpgpkeys=(
  'C92BAA713B8D53D3CAE63FC9E6974752F9704456' # André Silva
  '474402C8C582DAFBE389C427BCB7CF877E7D47A7' # Alexandre Oliva
  '684D54A189305A9CC95446D36B888913DDB59515' # Márcio Silva
  'ABAF11C65A2970B130ABE3C479BE3E4300411886' # Linus Torvalds
  '647F28654894E3BD457199BE38DBBDC86092693E' # Greg Kroah-Hartman
)

_kernelname=${pkgbase#linux-libre}
_mainlinekernelname=${pkgbase#linux-libre-lts}
_replacesarchkernel=("${_replacesarchkernel[@]/\%/${_kernelname}}")
_replacesmainlinearchkernel=("${_replacesmainlinearchkernel[@]/\%/${_mainlinekernelname}}")
_replacesoldkernels=("${_replacesoldkernels[@]/\%/${_kernelname}}")
_replacesoldmodules=("${_replacesoldmodules[@]/\%/${_kernelname}}")

case "${CARCH}" in
  i686|x86_64) KARCH=x86;;
esac

prepare() {
  cd "${srcdir}/linux-${_pkgver}"
  # add upstream patch
  if [ "${_pkgbasever}" != "${_pkgver}" ]; then
	real_path=$(readlink -f "${srcdir}/patch-${_pkgver}.xz")
	cp "$real_path" .
	xz -d "patch-${_pkgver}.xz"
  fi

  # add freedo as boot logo
  install -m644 -t drivers/video/logo \
    "${srcdir}/logo_linux_"{clut224.ppm,vga16.ppm,mono.pbm}

  # add latest fixes from stable queue, if needed
  # http://git.kernel.org/?p=linux/kernel/git/stable/stable-queue.git

  # ZEN: Add sysctl and CONFIG to disallow unprivileged CLONE_NEWUSER
  patch -p1 -i "${srcdir}/0001-ZEN-Add-sysctl-and-CONFIG-to-disallow-unprivileged-C.patch"

  # maintain the TTY over USB disconnects
  # http://www.coreboot.org/EHCI_Gadget_Debug
  patch -p1 -i "${srcdir}/0002-usb-serial-gadget-no-TTY-hangup-on-USB-disconnect-WI.patch"

  # # fix Atmel maXTouch touchscreen support
  # # https://labs.parabola.nu/issues/877
  # # http://www.fsfla.org/pipermail/linux-libre/2015-November/003202.html
  # patch -p1 -i "${srcdir}/0003-fix-Atmel-maXTouch-touchscreen-support.patch"

  # HID: quirks: Add Apple Magic Trackpad 2 to hid_have_special_driver list
  # https://bugzilla.kernel.org/show_bug.cgi?id=210241
  patch -p1 -i "${srcdir}/0004-HID-quirks-Add-Apple-Magic-Trackpad-2-to-hid_have_sp.patch"

  # kbuild: support byacc as alternative YACC to bison
  # https://patchwork.kernel.org/patch/11218023/
  patch -p1 -i "${srcdir}/0006-v2-kbuild-support-byacc-as-alternative-YACC-to-bison.patch"

  # sign-file: full functionality with modern LibreSSL
  # https://patchwork.kernel.org/patch/11446123/
  patch -p1 -i "${srcdir}/0007-sign-file-full-functionality-with-modern-LibreSSL.patch"

  cat "${srcdir}/config.${CARCH}" > ./.config

  # append pkgrel to extraversion
  sed -ri "s|^(EXTRAVERSION =.*\S).*|\1-${pkgrel}|" Makefile

  # don't run depmod on 'make install'. We'll do this ourselves in packaging
  sed -i '2iexit 0' scripts/depmod.sh

  # get kernel version
  yes "" | make ${MAKEFLAGS} prepare

  # load configuration
  # Configure the kernel. Replace the line below with one of your choice.
  #make menuconfig # CLI menu for configuration
  #make nconfig # new CLI menu for configuration
  #make xconfig # X-based configuration
  #make oldconfig # using old config from previous kernel version
  # ... or manually edit .config

  # rewrite configuration
  yes "" | make ${MAKEFLAGS} config >/dev/null
}

build() {
  cd "${srcdir}/linux-${_pkgver}"

  make ${MAKEFLAGS} LOCALVERSION= bzImage modules
}

_package() {
  pkgdesc="The ${pkgbase^} kernel and modules"
  [ "${pkgbase}" = "linux-libre-lts" ] && groups=('base')
  depends=('coreutils' 'kmod' 'mkinitcpio>=0.7')
  optdepends=('kernel-firmware: firmware files for Linux-libre'
              'crda: to set the correct wireless channels of your country')
  provides=("${_replacesarchkernel[@]/%/=${_archpkgver}}" "${_replacesoldkernels[@]}" "kernel=${_archpkgver}" "${_replacesmainlinearchkernel[@]}")
  conflicts=("${_replacesarchkernel[@]}" "${_replacesoldkernels[@]}" "${_replacesoldmodules[@]}" "${_replacesmainlinearchkernel[@]}")
  replaces=("${_replacesarchkernel[@]}" "${_replacesoldkernels[@]}" "${_replacesoldmodules[@]}" "${_replacesmainlinearchkernel[@]}")
  backup=("etc/mkinitcpio.d/${pkgbase}.preset")
  install=linux.install

  cd "${srcdir}/linux-${_pkgver}"

  # get kernel version
  _kernver="$(make LOCALVERSION= kernelrelease)"
  _basekernel=${_kernver%%-*}
  _basekernel=${_basekernel%.*}

  mkdir -p "${pkgdir}"/{lib/modules,lib/firmware,boot}
  install -Dm644 arch/$KARCH/boot/bzImage "${pkgdir}/boot/vmlinuz-${pkgbase}"
  make ${MAKEFLAGS} LOCALVERSION= INSTALL_MOD_PATH="${pkgdir}" INSTALL_MOD_STRIP=1 modules_install

  # set correct depmod command for install
  sed -e "s|%PKGBASE%|${pkgbase}|g;s|%KERNVER%|${_kernver}|g" \
    "${startdir}/${install}" > "${startdir}/${install}.pkg"
  true && install=${install}.pkg

  # install mkinitcpio preset file for kernel
  sed "s|%PKGBASE%|${pkgbase}|g" "${srcdir}/linux.preset" |
    install -D -m644 /dev/stdin "${pkgdir}/etc/mkinitcpio.d/${pkgbase}.preset"

  # install pacman hook for initramfs regeneration
  sed "s|%PKGBASE%|${pkgbase}|g" "${srcdir}/90-linux.hook" |
    install -D -m644 /dev/stdin "${pkgdir}/usr/share/libalpm/hooks/90-${pkgbase}.hook"

  # remove build and source links
  rm -f "${pkgdir}"/lib/modules/${_kernver}/{source,build}

  # # remove the firmware
  # rm -rf "${pkgdir}/lib/firmware"

  # make room for external modules
  ln -s "../extramodules-${_basekernel}${_kernelname}" "${pkgdir}/lib/modules/${_kernver}/extramodules"
  # add real version for building modules and running depmod from post_install/upgrade
  mkdir -p "${pkgdir}/lib/modules/extramodules-${_basekernel}${_kernelname}"
  echo "${_kernver}" > "${pkgdir}/lib/modules/extramodules-${_basekernel}${_kernelname}/version"

  # Now we call depmod...
  depmod -b "${pkgdir}" -F System.map "${_kernver}"

  # add kernel configuration file
  # https://issues.hyperbola.info/index.php?do=details&task_id=146
  install -D -m644 .config "${pkgdir}/boot/config-${pkgbase}"

  # install license file
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/$pkgname/COPYING"
}

_package-headers() {
  pkgdesc="Header files and scripts for building modules for ${pkgbase^} kernel"
  provides=("${_replacesarchkernel[@]/%/-headers=${_archpkgver}}" "${_replacesoldkernels[@]/%/-headers}" "${_replacesmainlinearchkernel[@]/%/-headers}")
  conflicts=("${_replacesarchkernel[@]/%/-headers}" "${_replacesoldkernels[@]/%/-headers}" "${_replacesmainlinearchkernel[@]/%/-headers}")
  replaces=("${_replacesarchkernel[@]/%/-headers}" "${_replacesoldkernels[@]/%/-headers}" "${_replacesmainlinearchkernel[@]/%/-headers}")

  install -dm755 "${pkgdir}/lib/modules/${_kernver}"

  cd "${srcdir}/linux-${_pkgver}"
  install -D -m644 Makefile \
    "${pkgdir}/lib/modules/${_kernver}/build/Makefile"
  install -D -m644 kernel/Makefile \
    "${pkgdir}/lib/modules/${_kernver}/build/kernel/Makefile"
  install -D -m644 .config \
    "${pkgdir}/lib/modules/${_kernver}/build/.config"
  install -D -m644 vmlinux \
    "${pkgdir}/lib/modules/${_kernver}/build/vmlinux"
  install -D -m644 System.map \
    "${pkgdir}/lib/modules/${_kernver}/build/System.map"
  install -D -m644 Module.symvers \
    "${pkgdir}/lib/modules/${_kernver}/build/Module.symvers"

  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/include"

  for i in acpi asm-generic clocksource config crypto drm dt-bindings \
    generated keys kunit kvm linux math-emu media memory misc net \
    pcmcia ras rdma scsi soc sound target trace uapi vdso video xen; do
    cp -a include/${i} "${pkgdir}/lib/modules/${_kernver}/build/include/"
  done

  # copy arch includes for external modules
  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/arch/${KARCH}"
  cp -a arch/${KARCH}/include "${pkgdir}/lib/modules/${_kernver}/build/arch/${KARCH}/"

  # copy files necessary for later builds
  cp -a scripts "${pkgdir}/lib/modules/${_kernver}/build"

  # fix permissions on scripts dir
  chmod og-w -R "${pkgdir}/lib/modules/${_kernver}/build/scripts"
  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/.tmp_versions"

  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/arch/${KARCH}/kernel"

  cp arch/${KARCH}/Makefile "${pkgdir}/lib/modules/${_kernver}/build/arch/${KARCH}/"

  if [ "${CARCH}" = "i686" ]; then
    cp arch/${KARCH}/Makefile_32.cpu "${pkgdir}/lib/modules/${_kernver}/build/arch/${KARCH}/"
  fi

  cp arch/${KARCH}/kernel/asm-offsets.s "${pkgdir}/lib/modules/${_kernver}/build/arch/${KARCH}/kernel/"

  # add dm headers
  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/drivers/md"
  cp drivers/md/*.h "${pkgdir}/lib/modules/${_kernver}/build/drivers/md"

  # add inotify.h
  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/include/linux"
  cp include/linux/inotify.h "${pkgdir}/lib/modules/${_kernver}/build/include/linux/"

  # add wireless headers
  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/net/mac80211/"
  cp net/mac80211/*.h "${pkgdir}/lib/modules/${_kernver}/build/net/mac80211/"

  # add dvb headers for external modules
  # http://bugs.archlinux.org/task/11194
  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/include/config/dvb/"
  cp include/uapi/linux/dvb/*.h "${pkgdir}/lib/modules/${_kernver}/build/include/config/dvb/"

  # add dvb headers for http://mcentral.de/hg/~mrec/em28xx-new
  # in reference to:
  # http://bugs.archlinux.org/task/13146
  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/dvb-frontends/"
  cp drivers/media/dvb-frontends/lgdt330x.h "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/dvb-frontends/"
  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/i2c/"
  cp drivers/media/i2c/msp3400-driver.h "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/i2c/"

  # add dvb headers
  # in reference to:
  # http://bugs.archlinux.org/task/20402
  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/usb/dvb-usb"
  cp drivers/media/usb/dvb-usb/*.h "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/usb/dvb-usb/"
  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/dvb-frontends"
  cp drivers/media/dvb-frontends/*.h "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/dvb-frontends/"
  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/tuners"
  cp drivers/media/tuners/*.h "${pkgdir}/lib/modules/${_kernver}/build/drivers/media/tuners/"

  # add xfs and shmem for aufs building
  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/fs/xfs"
  mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/mm"
  # removed in 3.17-gnu series
  # cp fs/xfs/xfs_sb.h "${pkgdir}/lib/modules/${_kernver}/build/fs/xfs/xfs_sb.h"

  # copy in Kconfig files
  for i in $(find . -name "Kconfig*"); do
    mkdir -p "${pkgdir}"/lib/modules/${_kernver}/build/`echo ${i} | sed 's|/Kconfig.*||'`
    cp ${i} "${pkgdir}/lib/modules/${_kernver}/build/${i}"
  done

  # add objtool for external module building and enabled VALIDATION_STACK option
  if [ -f tools/objtool/objtool ];  then
      mkdir -p "${pkgdir}/lib/modules/${_kernver}/build/tools/objtool"
      cp -a tools/objtool/objtool ${pkgdir}/lib/modules/${_kernver}/build/tools/objtool/
  fi

  chown -R root.root "${pkgdir}/lib/modules/${_kernver}/build"
  find "${pkgdir}/lib/modules/${_kernver}/build" -type d -exec chmod 755 {} \;

  # strip scripts directory
  find "${pkgdir}/lib/modules/${_kernver}/build/scripts" -type f -perm -u+w 2>/dev/null | while read binary ; do
    case "$(file -bi "${binary}")" in
      *application/x-sharedlib*) # Libraries (.so)
        /usr/bin/strip ${STRIP_SHARED} "${binary}";;
      *application/x-archive*) # Libraries (.a)
        /usr/bin/strip ${STRIP_STATIC} "${binary}";;
      *application/x-executable*) # Binaries
        /usr/bin/strip ${STRIP_BINARIES} "${binary}";;
      *application/x-pie-executable\;*) # Relocatable binaries
        /usr/bin/strip ${$STRIP_SHARED} "${binary}";;
    esac
  done

  # strip vmlinux
  strip -v $STRIP_STATIC "${pkgdir}/lib/modules/${_kernver}/build/vmlinux"

  # remove unneeded architectures
  find "${pkgdir}"/lib/modules/${_kernver}/build/arch -mindepth 1 -maxdepth 1 -type d -not -name "$KARCH" -exec rm -rf {} +

  # remove documentation
  rm -r "${pkgdir}/lib/modules/${_kernver}/build/Documentation"

  # remove broken symlinks
  find -L "${pkgdir}/lib/modules/${_kernver}/build" -type l -printf 'Removing %P\n' -delete

  # remove loose objects
  find "${pkgdir}/lib/modules/${_kernver}/build" -type f -name '*.o' -printf 'Removing %P\n' -delete

  # add symlink
  mkdir -p "$pkgdir/usr/src"
  ln -sr "${pkgdir}/lib/modules/${_kernver}/build" "$pkgdir/usr/src/$pkgbase"

  # install license file
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/$pkgname/COPYING"
}

_package-docs() {
  pkgdesc="Kernel hackers manual - HTML documentation that comes with the ${pkgbase^} kernel"
  provides=("${_replacesarchkernel[@]/%/-docs=${_archpkgver}}" "${_replacesoldkernels[@]/%/-docs}" "${_replacesmainlinearchkernel[@]/%/-docs}")
  conflicts=("${_replacesarchkernel[@]/%/-docs}" "${_replacesoldkernels[@]/%/-docs}" "${_replacesmainlinearchkernel[@]/%/-docs}")
  replaces=("${_replacesarchkernel[@]/%/-docs}" "${_replacesoldkernels[@]/%/-docs}" "${_replacesmainlinearchkernel[@]/%/-docs}")

  cd "${srcdir}/linux-${_pkgver}"

  mkdir -p "${pkgdir}/usr/share/doc/${pkgname}"
  cp -al Documentation/* "${pkgdir}/usr/share/doc/${pkgname}"
  find "${pkgdir}" -type f -exec chmod 444 {} \;
  find "${pkgdir}" -type d -exec chmod 755 {} \;

  # install license file
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/$pkgname/COPYING"
}

pkgname=("${pkgbase}" "${pkgbase}-headers" "${pkgbase}-docs")
for _p in ${pkgname[@]}; do
  eval "package_${_p}() {
    $(declare -f "_package${_p#${pkgbase}}")
    _package${_p#${pkgbase}}
  }"
done

# vim:set ts=8 sts=2 sw=2 et: