# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer: André Silva <emulatorman@hyperbola.info>

pkgname=libwacom
pkgver=0.24
pkgrel=1.hyperbola2
pkgdesc="Library to identify Wacom tablets and their features, with eudev support"
arch=('x86_64' 'i686')
url="https://sourceforge.net/apps/mediawiki/linuxwacom/index.php?title=Libwacom"
license=('Expat')
depends=('glib2' 'eudev' 'libgudev')
source=(https://sourceforge.net/projects/linuxwacom/files/libwacom/$pkgname-$pkgver.tar.bz2)
sha512sums=('331acb33ab798abf376f70647786c894014d5baa373cc66d53f1e77e77129ba78ec059f32f5cf3659a1fe3e8f9ff6ab3eb6eefd6090fc3c3bab4582ea25a5640')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -m755 -d ${pkgdir}/lib/udev/rules.d
  cd tools
  ./generate-udev-rules > ${pkgdir}/lib/udev/rules.d/65-libwacom.rules
}