# Maintainer (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor (Arch): Dan McGee <dan@archlinux.org>
# Maintainer: André Silva <emulatorman@hyperbola.info>
# Maintainer: Márcio Silva <coadde@hyperbola.info>
# Maintainer: Tobias Dausend <throgh@hyperbola.info>
# Contributor: Jesús E. <heckyel@hyperbola.info>
pkgbase=dash
pkgname=($pkgbase $pkgbase-shcompat)
pkgver=0.5.12
_debver=${pkgver}
_debrel=2
pkgrel=4
pkgdesc='POSIX compliant shell that aims to be as small as possible'
url="http://gondor.apana.org.au/~herbert/dash/"
arch=('i686' 'x86_64')
# src/mksignames.c show in COPYING license file.
# This code file is GPL-2 license and found in EXTRA_DIST directive
# (in the src/Makefile.am)
# But this file isn't not directly linked, not compiled and
# not included in this package.
license=('Modified-BSD')
depends=('grep' 'libedit' 'sed')
makedepends=('quilt')
provides=('ash')
conflicts=('ash')
install=dash.install
source=("https://deb.debian.org/debian/pool/main/d/dash/dash_${pkgver}.orig.tar.gz"
		"https://deb.debian.org/debian/pool/main/d/dash/dash_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('13bd262be0089260cbd13530a9cf34690c0abeb2f1920eb5e61be7951b716f9f335b86279d425dbfae56cbd49231a8fdffdff70601a5177da3d543be6fc5eb17'
            '7f4def6b962465a1695a6de95c6e08ac2c24f9a60ce92002220ef0b9b134234d0daf4dcba3e3db5853cd194da0ae1a1d04d1aee58b4aaae5f418ccc5b23f10b7')
prepare() {
 cd "${srcdir}/${pkgbase}-${pkgver}"
 if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
 # Debian patches
 export QUILT_PATCHES=debian/patches
 export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
 export QUILT_DIFF_ARGS='--no-timestamps'
 mv "$srcdir"/debian .
 quilt push -av
 fi
 autoreconf -fiv "${srcdir}/${pkgbase}-${pkgver}"
}
build() {
 mkdir "${srcdir}/build"
 cd "${srcdir}/build"
 "${srcdir}/${pkgbase}-${pkgver}/configure" \
 --prefix=/usr \
 --mandir=/usr/share/man \
 --exec-prefix="" \
 --with-libedit
 cd "${OLDPWD}"
 make -C "${srcdir}/build" V=1
}
package_dash() {
 make -C "${srcdir}/build" DESTDIR="${pkgdir}" install
 ln -s $pkgbase $pkgdir/bin/ash
 ln -s $pkgbase.1.gz $pkgdir/usr/share/man/man1/ash.1.gz
 # license
 install -Dm 644 "${srcdir}/${pkgbase}-${pkgver}/COPYING" -t \
		"${pkgdir}/usr/share/licenses/${pkgname}"
}
package_dash-shcompat() {
 pkgdesc='POSIX Shell compatibility for GNU Bourne Again SHell'
 groups=(base)
 depends=("$pkgbase")
 provides=('sh')
 conflicts=('sh')
 install=$pkgname.install
 install -dm755 $pkgdir/{bin,usr/share/man/man1}
 ln -s $pkgbase $pkgdir/bin/sh
 ln -s $pkgbase.1.gz $pkgdir/usr/share/man/man1/sh.1.gz
 # license
 install -Dm 644 "${srcdir}/${pkgbase}-${pkgver}/COPYING" -t \
		"${pkgdir}/usr/share/licenses/${pkgname}"
}
# vim:set ts=2 sw=2 et: