pkgname=bazelisk
pkgver=1.26.0
pkgrel=1
pkgdesc='A user-friendly launcher for Bazel.'
arch=('x86_64')
url="https://github.com/bazelbuild/bazelisk"
license=('Apache-2.0')
makedepends=(
    'go-bin'
    'git-legacy'
)
depends=(
    'glibc'
)
provides=('bazel')
conflicts=('bazel')
source=("https://github.com/bazelbuild/bazelisk/archive/refs/tags/v${pkgver}.tar.gz")
sha512sums=('a8eed55d57b19d625b4e999f232948addd37ffbb843ed254d7a13d4c187e8a8b38cea470310a701f0bdf1eec87e222ad43a24137e55156e0d41bfdf6b7391c0d')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  go mod tidy
  mkdir -p build/
}

build() {
  cd "$pkgname-$pkgver"
  export CGO_CPPFLAGS="${CPPFLAGS}"
  export CGO_CFLAGS="${CFLAGS}"
  export CGO_CXXFLAGS="${CXXFLAGS}"
  export CGO_LDFLAGS="${LDFLAGS}"
  export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
  go build -o build .
}

package() {
  cd "$pkgname-$pkgver"
  install -Dm755 build/$pkgname "$pkgdir"/usr/bin/$pkgname
  ln -s /usr/bin/bazelisk $pkgdir/usr/bin/bazel
}