1 files changed, 44 insertions, 0 deletions
diff --git a/abseil-cpp/PKGBUILD b/abseil-cpp/PKGBUILD
new file mode 100644
index 0000000..e70c980
--- /dev/null
+++ b/abseil-cpp/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Cory Sanin <corysanin@artixlinux.org>
+# Contributor: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
+# Contributor: Christian Heusel <gromit@archlinux.org>
+# Contributor: Aleksandar Trifunović <akstrfn at gmail dot com>
+
+pkgname=abseil-cpp
+pkgver=20250127.1
+pkgrel=2
+pkgdesc="Collection of C++ library code designed to augment the C++ standard library"
+arch=('x86_64')
+url='https://abseil.io'
+license=('Apache-2.0')
+depends=('gcc-libs' 'glibc' 'gtest')
+makedepends=('cmake')
+source=("https://github.com/abseil/abseil-cpp/archive/$pkgver/$pkgname-$pkgver.tar.gz"
+         scoped-mock-log.patch)
+sha256sums=('b396401fd29e2e679cace77867481d388c807671dc2acc602a0259eeb79b7811'
+            'a6cbc612a2b96fcbd52d081e03e8581107ceb4827edb19d96510a31c568e1396')
+
+prepare() {
+  cd "$srcdir/$pkgname-$pkgver"
+  patch -p1 -i ../scoped-mock-log.patch # Install target needed by protobuf
+}
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+  cmake -Bbuild \
+    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
+    -DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG" \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_CXX_STANDARD=17 \
+    -DBUILD_SHARED_LIBS=ON \
+    -DABSL_BUILD_TEST_HELPERS=ON \
+    -DABSL_USE_EXTERNAL_GOOGLETEST=ON \
+    -DABSL_FIND_GOOGLETEST=ON \
+    -DABSL_BUILD_TESTING=OFF
+  cd build
+  cmake --build . --target all
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver/build"
+  DESTDIR="$pkgdir" cmake --install .
+}